作成者	カテゴリ	返答の対象		公開
a' 05/30/2022 12:48 PM		リッチテキストの画像添付の有無チェック

DXLで出力してみると解析出来ます。
下記の関数では、調べたいリッチテキストアイテムをダミーの文書にコピーしてその文書をDXLにて吐き出させた結果をDOMパーサでDOM化して、中に Picture 要素があるかどうかで判断しています。



'------------------------------------------------------------------------------
' リッチテキストアイテムに画像が添付されているかどうかを調べる
' riitem : 調査対象となるリッチテキストアイテム
'------------------------------------------------------------------------------
Function HasRichtextPicture( rtitem As Variant ) As Boolean
HasRichtextPicture = False
Dim session As New NotesSession
Dim db As NotesDatabase
Dim doc As NotesDocument
Dim exporter As NotesDXLExporter
Dim domParser As NotesDOMParser
Dim docNode As NotesDOMDocumentNode
Dim domNodeList As NotesDOMNodeList

Set db = session.CurrentDatabase
Set exporter = session.CreateDXLExporter
Set domParser = session.CreateDOMParser()
'リッチテキスト アイテムをダミードキュメントにコピー
Set doc = db.CreateDocument
Call rtitem.CopyItemToDocument( doc, "Rtitem" )
'ダミードキュメントをDXLに吐き出す
'添付ファイルはExportしないようにする
exporter.OmitRichtextAttachments = True
Call exporter.SetInput( doc )
Call exporter.SetOutput( domParser )
Call exporter.Process
Set docNode = domParser.Document
' Pictureがあれば、画像添付されていると判断
Set domNodeList = docNode.GetElementsByTagName( "picture" )
If domNodeList.NumberOfEntries > 0 Then
HasRichtextPicture = True
End If
End Function